简而言之，我尝试使用网络中每个实例的对象来建模网络拓扑。此外，我还有一个顶级管理器类，负责管理这些对象并执行完整性检查。文件结构看起来像这样(我省略了大部分目标文件，因为它们的结构都非常相同):

Manager.pm 
Constants.pm 
Classes/ 
  +- Machine.pm 
  +- Node.pm 
  +- Object.pm 
  +- Switch.pm 

从事 OOP 工作多年，我是代码重用等的粉丝，因此我在对象之间设置了继承，继承树(在此示例中)如下所示:

Switch  -+-> Node -+-> Object 
Machine -+ 

所有这些对象的结构如下:

package Switch; 
use parent qw(Node); 
 
sub buildFromXML { 
  ... 
} 
sub new { 
  ... 
} 
 
# additonal methods 

现在有趣的部分:

问题 1

如何在不静态输入名称的情况下确保正确加载所有这些对象？
根本问题是:如果我只是 require "$_" foreach glob("./Classes/*");我收到许多“子程序新重新定义在”错误。我也玩过 use parent qw(-norequire Object) , Module::Find和其他一些 @INC各种组合的修改，简而言之:它不起作用。目前我正在静态导入所有使用的类，它们会自动导入它们的父类。
所以基本上我要问的是:(perl-)正确的方法是什么？
高级:能够创建更复杂的文件夹结构(因为会有很多对象)并且仍然具有继承+“自动加载”，这将非常有帮助

问题 2 - 已解决

我怎样才能“分享我的进口”？我使用了几个库(我自己的，包含一些辅助函数， LibXML， Scalar::Util 等)，我想在我的对象中共享它们。 (这背后的原因是，我可能需要为所有对象添加另一个通用库，并且很有可能会有超过 100 个对象 - 手动编辑所有对象并使用正则表达式/脚本执行此操作在理论上可行，但是这似乎不是最干净的解决方案)
我尝试了什么:

导入 Manager.pm 中的所有内容-> 在 Manager 包中工作 - 给我类似“未定义的子例程 &Switch::trace 调用”

之类的错误

创建 include.pl文件和 do/require/use它在每个对象中 - 给了我同样的错误。

还有一些我很遗憾不记得的东西

include.pl基本上看起来像这样:

use lib_perl; 
use Scalar::Util qw(blessed); 
use XML::LibXML; 
use Data::Dumper; 
use Error::TryCatch; 
... 

我再次问:正确的方法是什么？我是否使用了正确的方法并且只是在执行中失败了，还是应该完全改变我的结构？
为什么我当前的代码不能很好地工作并不重要，到目前为止，为这些问题提供正确、干净的方法就足够了:)

编辑:完全忘记 perl 版本 -_- 旁注:我无法升级 perl，因为我需要使用 5.8 的库:/

C:\> perl -version 
This is perl, v5.8.8 built for MSWin32-x86-multi-thread 
(with 50 registered patches, see perl -V for more detail) 
 
Copyright 1987-2006, Larry Wall 
 
Binary build 820 [274739] provided by ActiveState http://www.ActiveState.com 
Built Jan 23 2007 15:57:46 

请您参考如下方法:

这只是对问题 2(共享导入)的部分回答。
加载模块(通过 use )做了两件事:

编译模块并在命名空间层次结构中安装内容(这是共享的)。见 perldoc -f require .

调用import sub 在每个加载的模块上。这会将一些子项或常量等加载到调用者的命名空间中。这是 Exporter 的过程类在很大程度上隐藏在视线之外。这部分对于使用没有全名的 subs 等很重要，例如max而不是 List::Util::max .见 perldoc -f use .

让我们查看以下三个模块: A , B和 User .

{ 
   package A; 
   use List::Util qw(max); 
   # can use List::Util::max 
   # can use max 
} 
{ 
   package User; 
   # can use List::Util::max -> it is already loaded 
   # cannot use max, this name is not defined in this namespace 
} 

包 B定义一个子 load将预定义的模块和子列表加载到调用者命名空间中:

{ 
   package B; 
   sub load { 
     my $package = (caller())[0]; # caller is a built-in, fetches package name 
 
     eval qq{package $package;} . <<'FINIS' ; 
       use List::Util qw(max); 
       # add further modules here to load 
       # you can place arbitrarily complex code in this eval string 
       # to execute it in all modules that call this sub. 
       # (e.g. testing and registering) 
       # However, this is orthogonal to OOP. 
FINIS 
 
     if ($@) { 
       # Do error handling 
     } 
   } 
} 

里面 eval 'd 字符串，我们暂时切换到调用者包中然后加载指定模块。这意味着 User包代码现在看起来像这样:

{ 
   package User; 
   B::load(); 
   # can use List::Util::max 
   # can use max 
} 

但是，您必须确保 load sub 本身已经加载。 use B如果有疑问。最好执行 B::load()在 BEGIN阶段，在编译模块的其余部分之前:

{ 
  package User; 
  BEGIN {use B; B::load()} 
  # ... 
} 

相当于

{ 
  package User; 
  use B; 
  use List::Util qw(max); 
  # ... 
} 

蒂姆托迪。虽然我发现 eval ing 代码非常困惑和危险，这是我在这种情况下追求的方式(而不是 do ing 文件，它相似但具有不同的副作用)。相比之下，手动处理包命名空间中的 typeglob 简直是天方夜谭，复制粘贴模块名称列表就像回到甚至没有 C 预处理器的时代。

编辑: Import::Into
... 是一个通过有趣的方法接口(interface)提供此功能的 CPAN 模块。使用这个模块，我们将重新定义我们的 B打包方式如下:

{ 
  package B; 
  use List::Util;   # you have to 'use' or 'require' this first, before using 'load'. 
  use Import::Into; # has to be installed from CPAN first 
  sub load { 
    my $package = caller; 
    List::Util->import::into($package, qw(max)); 
    # should work too: strict->import::into($package); 
    # ... 
  } 
} 

该模块隐藏了所有的脏工作( eval ing)，并执行方法调用解析体操以允许将 pragma 导入其他命名空间。